ワークシートとユーザーフォームの両方でコネクタを選択

昨日は、ワークシート上のコネクタをクリックし、その結果をユーザーフォームのリストボックスに表示しました。

infoment.hatenablog.com

今日はその機能を維持しつつ、リストボックス内のコネクタ名を選ぶことで、ワークシート上のコネクタを選択することに挑戦です。

今日やりたいこと

リストボックス内のリストを選択することで、対応するワークシート上のコネクタを選択状態にします。

必要なこと

1. ユーザーフォームの改修

昨日、ユーザーフォーム内にあった幾つかの機能を、クラスモジュール側に移しました。従って今日は主に、抜けて穴が開いた箇所を綺麗にすることにします。

１．ユーザーフォームの改修

今日改修するのは、コネクタの編集に特化したユーザーフォーム：EditConnectorForm です。追加と削除を繰り返してきたので、今回は全文を載せることにします。

【ユーザーフォームのモジュール】（EditConnectorForm）

ちょっと長いので、今回も畳んでおきます。

▶クリックで展開

モジュールレベル変数

Option Explicit
Dim SC As ShapeClass
' コネクタ始端のオートシェイプ
Dim start_shape As Shape
' コネクタ始端の接続位置
Dim StartPosition As Long
' コネクタ終端のオートシェイプ
Dim end_shape As Shape
' コネクタ終端の接続位置
Dim EndPosition As Long

ブロック追加ボタンクリック

Private Sub AddChartButton_Click()

    ' コネクタ削除
    SC.myShape.Delete
    
    On Error Resume Next
    Dim PositionRelationIndex As Long
        PositionRelationIndex = SC.GetPositionRelation(start_shape, end_shape)
    Dim myLeft As Long
    Dim myTop As Long
        Select Case PositionRelationIndex
            ' 真上、真下の場合
            Case 1, 3
                myLeft = start_shape.Left
                myTop = (start_shape.Top + end_shape.Top) / 2
            ' 左横、右横の場合
            Case 2, 4
                myLeft = (start_shape.Left + end_shape.Left) / 2
                myTop = start_shape.Top
            ' 左斜め上、右斜め上の場合
            Case 5, 8
                myLeft = end_shape.Left
                myTop = start_shape.Top
            ' 左斜め下、右斜め下の場合
            Case 6, 7
                myLeft = start_shape.Left
                myTop = end_shape.Top
        End Select    
    Dim myHeight As Double
        myHeight = end_shape.Height
    Dim myWidth As Double
        myWidth = start_shape.Width
    
    Set SC.myShape = ActiveSheet.Shapes.AddShape(msoShapeFlowchartProcess, myLeft, myTop, myWidth, myHeight)
        SC.myShape.TextFrame2.TextRange.Characters.Text = AddChartTextBox.Value
        SC.myShape.OnAction = "SelectShape"
        SC.SetFormat
    
    Dim AddShape(1 To 3) As Shape
    Set AddShape(1) = start_shape
    Set AddShape(2) = SC.myShape
    Set AddShape(3) = end_shape
    
    Dim i As Long
        For i = 1 To 2
            ConnectShape AddShape(i), AddShape(i + 1)
        Next
 
    Set ECoC = New EditConnectorClass
    Call ECoC.UpdateConnectorList
    
    If EditChartFlag = True Then
        Set EChC = New EditChartClass
        With EditChartForm.ListBox1
            .Clear
            .List = EChC.ShapeList
            Call EChC.UpdateOrder
        End With
    End If

End Sub

追加ブロック用テキスト

Private Sub AddChartTextBox_Change()
    Call ECoC.ControlAddChartButton
End Sub

リストボックスの項目選択

Private Sub ListBox2_Change()
    On Error Resume Next
    Dim ConnectorName As String
        ConnectorName = ListBox2.List(ListBox2.ListIndex)
        If Err.Number = 381 Then
            Exit Sub
        End If
    
    Set SC = New ShapeClass
    Set SC.myShape = ActiveSheet.Shapes(ConnectorName)
        SC.myShape.Select
    
    Set ECoC = New EditConnectorClass
        
    With ECoC
        .ConnectorName = ConnectorName
        Set start_shape = .start_shape
            StartPosition = .StartPosition
        Set end_shape = .end_shape
            EndPosition = .EndPosition
        Call .ControlAddChartButton
    End With
    
End Sub

始端用スピンボタン

Private Sub StartSpinButton_Change()
    If Not start_shape Is Nothing Then
        SC.myShape.ConnectorFormat.BeginConnect start_shape, StartPosition
    End If
    
    Select Case StartSpinButton.Value
        Case StartSpinButton.Max, StartSpinButton.Min
            StartSpinButton.Value = StartSpinButton.Max / 2
    End Select
    
End Sub

Private Sub StartSpinButton_SpinUp()
    StartPosition = StartPosition Mod 4 + 1
End Sub

Private Sub StartSpinButton_SpinDown()
    Select Case StartPosition
        Case 1
            StartPosition = 4
        Case Else
            StartPosition = StartPosition - 1
    End Select
End Sub

終端用スピンボタン

Private Sub EndSpinButton_Change()
    If Not end_shape Is Nothing Then
        SC.myShape.ConnectorFormat.EndConnect end_shape, EndPosition
    End If
    
    Select Case EndSpinButton.Value
        Case EndSpinButton.Max, EndSpinButton.Min
            EndSpinButton.Value = EndSpinButton.Max / 2
    End Select
End Sub

Private Sub EndSpinButton_SpinUp()
    EndPosition = EndPosition Mod 4 + 1
End Sub

Private Sub EndSpinButton_SpinDown()
    Select Case EndPosition
        Case 1
            EndPosition = 4
        Case Else
            EndPosition = EndPosition - 1
    End Select
End Sub

ユーザーフォームの初期化

Private Sub UserForm_Initialize()
    StartSpinButton.Value = StartSpinButton.Max / 2
    EndSpinButton.Value = EndSpinButton.Max / 2
End Sub

ユーザーフォームを閉じるときのフラグ変更

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    If CloseMode = VBA.VbQueryClose.vbFormControlMenu Then
        EditConnectorFlag = False
    End If
End Sub

結果

ワークシートとユーザーフォームの両方で、コネクタの選択が可能になりました。
ついでに、追加したブロックにもOnActionプロパティでマクロを登録すると共に、ユーザーフォームのリストを更新させてみました。

今回は、thomさんに教えていただいたGIFアニメーションを張り付けてみました（いつも有難うございます）。
百読（？）は一見に如かず、ですね。静止画像からアニメーションになった分だけ、分かり易くなったのではないかと思います。

次回に続きますが、そろそろ、いよいよ終盤（幕間）です。

参考まで。