ＶＢＡを用いた集合の理解 ③ 集合Ａは集合Ｂの部分集合

先日から高校数学の学び直しとして、ＶＢＡを用いた集合の理解に挑戦している。
infoment.hatenablog.com
今日も、先日の続きから。

先日までは、要素ａが集合Ａに含まれるか否かの判定を、そして更に集合Ａを
一次元配列として、要素ａの追加と削除を行ってみた。

今回は、集合Ａが集合Ｂに含まれるか？の判定を行ってみる。

• Ａ＝Ｂ：集合Ａと集合Ｂは等しい ⇒ 配列Ａと配列Ｂは等しい
• Ａ⊂Ｂ：集合Ａは集合Ｂの部分集合 ⇒ 配列Ａは配列Ｂに含まれる
• Ａ⊆Ｂ：Ａ＝ＢまたはＡ⊂Ｂ

manabitimes.jp

クラスモジュール（MathSet）

まず、Ａ⊂Ｂを作成する。配列Ａの要素が全て配列Ｂに含まれていて、且つ、
配列Ｂの要素が一つでもＡに含まれなければ、Ｂの一部がＡということになる。

前々回作成した ↓ こちらは、今回も使用するので再掲。

' 指定文字列が、ある集合の要素であるか否かを返す。
' a ∈ Ａ：ａは集合Ａの要素である。
Public Function IsElement(ByVal element As Variant, _
                          ByVal target_set As Variant, _
                       Optional LookAt As XlLookAt = xlWhole) As Boolean
        
    ' 集合ではないものが指定された場合、Falseを返す。
        If Not IsArray(target_set) Then Exit Function
    
    ' 配列内の値と順にelementを照合し、同じものがある時点でTrueを返す。
    ' 従って、この関数はtarget_set内で複数の同じ値が含まれる場合を除外しない。
    Dim a As Variant
        If LookAt = xlPart Then element = "*" & element & "*"
    
        For Each a In target_set
            If a Like element Then
                IsElement = True
                Exit Function
            End If
        Next
        
End Function

' 集合Ａが、集合Ｂに含まれるか否かを確認する（真部分集合）。
' Ａ ⊂ Ｂ
' ※配列Ａと配列Ｂの次元数が一致していなくとも、配列Ａの
' 　全ての要素が配列Ｂに包含されているならば、Trueを返す。
Public Function IsProperSubset(ByVal set_A As Variant, _
                               ByVal set_B As Variant) As Boolean
                         
        If Not IsArray(set_A) Or Not IsArray(set_B) Then Exit Function
    
    Dim a As Variant
        
        ' ＢにないものがＡにあれば、その時点で部分集合ではない。
        For Each a In set_A
            If Not IsElement(a, set_B) Then
                Exit Function
            End If
        Next
        
        ' 上述の処理を経たうえで、Ｂにあるものが全てＡにあれば、
        ' ＡとＢは等しいといえる（真部分集合とは言えない）。
        ' 従って、ＢにあってＡにないものが一つでも存在する時点で、
        ' ＡはＢの真部分集合（Ａ⊂Ｂ）と言える。
        For Each a In set_B
            If Not IsElement(a, set_A) Then
                IsProperSubset = True
            End If
        Next

End Function

次いで各要素の総当たりにより、Ａ＝Ｂを判定する。

' 集合Ａが、集合Ｂと等しいか否かを確認する。
' Ａ＝Ｂ
' ※配列Ａと配列Ｂの次元数が一致していなくとも、配列Ａと
' 　配列Ｂの要素が互いにすべて含まれるならば、Trueを返す。
Public Function IsEqual(ByVal set_A As Variant, _
                        ByVal set_B As Variant) As Boolean
                        
        If Not IsArray(set_A) Or Not IsArray(set_B) Then
            Exit Function
        End If
        
    Dim a As Variant
        For Each a In set_A
            If Not IsElement(a, set_B) Then
                Exit Function
            End If
        Next
        
        For Each a In set_B
            If Not IsElement(a, set_A) Then
                Exit Function
            End If
        Next
        
        IsEqual = True
        
End Function

最後に、こちらを作成。

' 集合Ａが、集合Ｂに含まれるか否かを確認する（部分集合）。
' Ａ ⊆ Ｂ
' ※配列Ａと配列Ｂの次元数が一致していなくとも、配列Ａの
' 　全ての要素が配列Ｂに包含されているかまたは等しいなら
'　 Trueを返す。
Public Function IsSubset(ByVal set_A As Variant, _
                         ByVal set_B As Variant) As Boolean
                        
        If Not IsArray(set_A) Or Not IsArray(set_B) Then
        ElseIf IsProperSubset(set_A, set_B) Or IsEqual(set_A, set_B) Then
            IsSubset = True
        End If
        
End Function

標準モジュール

それでは、簡単なテストを一つ。

Sub test()

    Dim MS As VBAProject.MathSet
    Set MS = New VBAProject.MathSet
        
    Dim 果物1 As Variant
        果物1 = Array("りんご", "みかん", "ばなな")
    Dim 果物2 As Variant
        果物2 = Array("りんご", "みかん", "ばなな")
                
    Debug.Print "果物2⊂果物1：" & MS.IsProperSubset(果物2, 果物1)
    Debug.Print "果物2＝果物1：" & MS.IsEqual(果物2, 果物1)
    Debug.Print "果物2⊆果物1：" & MS.IsSubset(果物2, 果物1)

    Dim 果物3 As Variant
        果物3 = Array("ぶどう", "れもん")

    Debug.Print "果物3⊂果物1：" & MS.IsProperSubset(果物3, 果物1)
    Debug.Print "果物3＝果物1：" & MS.IsEqual(果物3, 果物1)
    Debug.Print "果物3⊆果物1：" & MS.IsSubset(果物3, 果物1)

    Dim 果物4 As Variant
        果物4 = Array("りんご", "ばなな")

    Debug.Print "果物4⊂果物1：" & MS.IsProperSubset(果物4, 果物1)
    Debug.Print "果物4＝果物1：" & MS.IsEqual(果物4, 果物1)
    Debug.Print "果物4⊆果物1：" & MS.IsSubset(果物4, 果物1)

End Sub

結果がこちら。

段々と充実してきた。
次回は、和集合と積集合に挑戦です。

参考まで。