リストボックスから二つだけ選ばせたい ② 三つ以上選ばせない

昨日はリストボックスから二つだけ選ばせる方策として、選択数が二つ以外の時は投票ボタンを無効化してみた。
infoment.hatenablog.com
しかしこの方法だと、選択項目が１００個ある場合、１００個全て選べてしまう。９８個分の選択解除を行うまで投票ボタンが押せないというのは、寂しい話だ。

そこで今日は、上記のような事態にならない工夫に挑戦する。
f:id:Infoment:20190106110820p:plain

今回立てた作戦は、こうだ。

３個目を選んだ際、１個目の選択を解除する。

これなら、選ばれている項目数は常に２個以下になる。

ユーザーフォーム

まず選択順が分かるように、リストボックスを２列にする。
f:id:Infoment:20190106111117p:plain

ついでに、昨日のリストに「うどん」が二つあったので、コッソリ削除。

何個選ばれているか？はたびたび登場するので、昨日作成したユーザー定義関数：JudgeSpecifiedNumberから独立させた。

Private Function JudgeSpecifiedNumber(Optional n As Long = 2) As Boolean
    If Counter = n Then
        JudgeSpecifiedNumber = True
    Else
        JudgeSpecifiedNumber = False
    End If
End Function

Private Property Get Counter() As Long
    Counter = 0
    Dim i As Long
        For i = 0 To ListBox1.ListCount - 1
            If ListBox1.Selected(i) Then
                Counter = Counter + 1
            End If
        Next
End Property

次いで、ListBox1_MouseUpを少し改造する。
以下のように場合分けしてみた。

① 選択数が０のとき：
　ListBox1をリセットする。

② 選択数が１のとき：
　選択された項目について、選択順を１にする。
　それ以外の項目は、全て選択順を０にする。

③ 選択数が２のとき：
　選択された項目について、選択順が１の場合はそのままに。
　選択された項目について、選択順が０ならば２にする。
　それ以外の項目は、全て選択順を０にする。
　※「３つの選択項目から１つ減らされた場合」は考慮不要。

④ 選択数が３のとき：
　選択された項目について、選択順が１の場合は０にして選択解除。
　選択された項目について、選択順が２の場合は１にする。
　選択された項目について、選択順が０の場合は２にする。
　それ以外の項目は、全て選択順を０にする。
　※これにより、３つ以上の項目が選択された状態は存在しえない。

コード化してみる。

Private Sub ListBox1_MouseUp(ByVal Button As Integer, _
                             ByVal Shift As Integer, _
                             ByVal X As Single, _
                             ByVal Y As Single)
    Dim i As Long
    Select Case Counter
        Case 0
            ListBox1.Clear
            ListBox1.List = myList
        
        Case 1
            For i = 0 To ListBox1.ListCount - 1
                If ListBox1.Selected(i) Then
                    ListBox1.List(i, 1) = 1
                Else
                    ListBox1.List(i, 1) = 0
                End If
            Next
        
        Case 2
            For i = 0 To ListBox1.ListCount - 1
                If ListBox1.Selected(i) Then
                    ListBox1.List(i, 1) = 2 - ListBox1.List(i, 1)
                Else
                    ListBox1.List(i, 1) = 0
                End If
            Next
        
        Case 3
            For i = 0 To ListBox1.ListCount - 1
                If ListBox1.Selected(i) Then
                    Select Case ListBox1.List(i, 1)
                        Case 1
                            ListBox1.List(i, 1) = 0
                            ListBox1.Selected(i) = False
                        Case 2
                            ListBox1.List(i, 1) = 1
                        Case 0
                            ListBox1.List(i, 1) = 2
                    End Select
                Else
                    ListBox1.List(i, 1) = 0
                End If
            Next
    End Select
                             
    VoteButton.Enabled = JudgeSpecifiedNumber(2)
End Sub